sndbuf sL => dac.left;
sndbuf sR => dac.right;
sinosc n => blackhole;		//posLFO

2::minute => dur T; 			//script duration
[10000,13000] @=> int playTime[];	//play rand ms range
[50,60] @=> int posTime[];	//pos rand ms range
0.2 => float playG;
0.5 => float posG;
1 => float playRand;			//* to re-randomize within single play	
(1./105.)::second => dur posSR;	//pos SR	

0.007 => n.freq;			//posLFO freq
100000 => float jump;		//sample access range

0.8 => float speedBounds;
6 => int harmSteps;

("./wavs/rec2L.wav") => sL.read;
("./wavs/rec2R.wav") => sR.read;
1 => sL.loop => sR.loop;
float speed;

T + now => time later;
while (now < later)
{
	//play
	playG => sL.gain => sR.gain;
	std.rand2(playTime[0],playTime[1])::ms => dur playDur;
	now + playDur => time laterPlay;
	while (now < laterPlay)
	{
	speedBounds / (((std.rand2(1,2) - 1.5)*2.)*std.rand2(1,harmSteps)) => speed;
	speed => sL.play => sR.play;
	playDur / playRand => now;
	}
	
	//pos
	0 => sL.play => sR.play;
	posG => sL.gain => sR.gain;
	std.rand2(posTime[0],posTime[1])::ms => dur posDur;	
	now + posDur => time laterPos;
	while (now < laterPos)
	{
	std.fabs(((n.last()/2 + 0.5)*jump)) $ int => sL.pos => sR.pos;
	posSR => now;
	}
}